Ingegneria Forum

Tu possiedi la versione 06 in cui non avevo ancora apportato la correzione al valore impostato da DocHolly.

In ogni caso, proprio con riferimento alla funzione che hai riportato, il valore di  epsSmax NON SERVE ed infatti in una successiva mia revisione ho tolto quel parametro dalla funzione.

Code: [Select]

Public Function SigmaC(eps As Double, sigmaC_max As Double, forma As Integer, _
                                Optional Emodulus As Double = 0#, _
                                Optional epsCmax As Double = 0.0035, _
                                Optional epsCrif As Double = 0.002) As Double
'Restituisce la tensione del calcestruzzo corrispondente alla deformazione epsilon data
'Parametri:
'   eps = deformazione epsilon di cui calcolare la tensione sigma
'   sigma_max = tensione massima (MPa)
'   forma = parametro di forma del diagramma:
'           forma = 1 => parabola-rettangolo EC2
'           forma = 2 => perfettamente elastico lineare per compressione (il modulo di elasticità è definito da epsCmax)
'           forma = 3 => elasto-plastico (il modulo di elasticità se non definito è calcolato da epsCrif)
'   Emodulus = modulo di elasticità (necessario per forma pari a ?) (MPa)
'   epsSmax = deformazione limite dell'acciaio
'   epsCmax = deformazione limite del cls
'   epsCrif = deformazione limite del cls per compressione semplice

If forma = 1 Then
    Select Case eps
        Case -epsCmax To -epsCrif
            SigmaC = -sigmaC_max
        Case -epsCrif To 0
            SigmaC = -sigmaC_max * (1 - (1 - Abs(eps) / epsCrif) ^ 2) 'secondo EC2
        Case Else
            SigmaC = 0#
    End Select
    Exit Function
End If

If forma = 2 Then
    If eps < 0 Then
        SigmaC = eps * (sigmaC_max / epsCmax)
    Else
        SigmaC = 0#
    End If
    Exit Function
End If

If forma = 3 Then
    If (Emodulus = 0 And epsCrif <> 0) Then Emodulus = sigmaC_max / epsCrif
    Select Case eps
        Case -epsCmax To -epsCrif
            SigmaC = -sigmaC_max
        Case -epsCrif To 0
            SigmaC = eps * Emodulus
        Case Else
            SigmaC = 0#
    End Select
    Exit Function
End If

SigmaC = 0#

End Function

Mentre nella omologa funzione che serve per determinare la tensione nell'acciaio ho impostato epsSmax a 67.5 millesimi

Code: [Select]

Public Function SigmaS(eps As Double, sigmaS_max As Double, forma As Integer, _
                                Optional Emodulus As Double = 210000#, _
                                Optional epsSmax As Double = 0.0675) As Double
'Restituisce la tensione del'acciaio corrispondente alla deformazione epsilon data
'Parametri:
'   eps = deformazione epsilon di cui calcolare la tensione sigma
'   sigmaS_max = tensione massima (MPa)
'   forma = parametro di forma del diagramma:
'           forma = 1 => elasto-plastico
'           forma = 2 => perfettamente elastico lineare (il modulo di elasticità è definito da epsSmax)
'           forma = 3 => elasto-plastico incrudente (da sviluppare!)
'   Emodulus = modulo di elasticità (necessario per forma pari a 1) (MPa)
'   epsSmax = deformazione limite dell'acciaio
'   epsCmax = deformazione limite del cls
'   epsCrif = deformazione limite del cls per compressione semplice

Dim epsSrif As Double

If Emodulus <> 0 Then
    epsSrif = sigmaS_max / Emodulus
Else
    epsSrif = 0#
End If

If forma = 1 Then
    Select Case eps
        Case -epsSmax To -epsSrif
            SigmaS = -sigmaS_max
        Case -epsSrif To epsSrif
            SigmaS = eps * Emodulus
        Case epsSrif To epsSmax
            SigmaS = sigmaS_max
        Case Else
            SigmaS = 0#
    End Select
    Exit Function
End If

If forma = 2 Then
    SigmaS = eps * (sigmaS_max / epsSmax)
    Exit Function
End If

SigmaS = 0#

End Function


Forse è meglio che ti passi l'ultima versione?

Io ho la versione 01 che hai postato su ingforum.
Sarebbe possibile rendere pubblica anche questa versione più recente?
Credo che faresti cosa gradita a tutti.

Willy

nella versione 8 sarebbe interessante ci fosse anche il momento resistente in direzione trasversale.

Mentre nella omologa funzione che serve per determinare la tensione nell'acciaio ho impostato epsSmax a 67.5 millesimi

Code: [Select]

Public Function SigmaS(eps As Double, sigmaS_max As Double, forma As Integer, _
                                Optional Emodulus As Double = 210000#, _
                                Optional epsSmax As Double = 0.0675) As Double
'Restituisce la tensione del'acciaio corrispondente alla deformazione epsilon data
'Parametri:
'   eps = deformazione epsilon di cui calcolare la tensione sigma
'   sigmaS_max = tensione massima (MPa)
'   forma = parametro di forma del diagramma:
'           forma = 1 => elasto-plastico
'           forma = 2 => perfettamente elastico lineare (il modulo di elasticità è definito da epsSmax)
'           forma = 3 => elasto-plastico incrudente (da sviluppare!)
'   Emodulus = modulo di elasticità (necessario per forma pari a 1) (MPa)
'   epsSmax = deformazione limite dell'acciaio
'   epsCmax = deformazione limite del cls
'   epsCrif = deformazione limite del cls per compressione semplice

Dim epsSrif As Double

If Emodulus <> 0 Then
    epsSrif = sigmaS_max / Emodulus
Else
    epsSrif = 0#
End If

If forma = 1 Then
    Select Case eps
        Case -epsSmax To -epsSrif
            SigmaS = -sigmaS_max
        Case -epsSrif To epsSrif
            SigmaS = eps * Emodulus
        Case epsSrif To epsSmax
            SigmaS = sigmaS_max
        Case Else
            SigmaS = 0#
    End Select
    Exit Function
End If

If forma = 2 Then
    SigmaS = eps * (sigmaS_max / epsSmax)
    Exit Function
End If

SigmaS = 0#

End Function


La funzione a cui ti riferisci e' quella che ho preso dal lavoro dell'ing. Cattivelli con la sola modifica dell'allungamento a rottura dell'acciaio pari a 67.5/1000. Cosa avesse intenzione di fare non ne ho proprio idea dato che penso non l'abbia usata nemmeno lui nel suo foglio CMN.xls.